【宏】忘忧景久的常用宏——奶德篇

写在前面：

这些宏是根据我的个人习惯对小德的形态和技能做出的整合，因为宏本身的特性，使用不当可能会造成与想象中不同的后果，请斟酌后自行选择使用。当然，如果能给喜欢自己写宏的玩家一点灵感，那将是最大的价值！

#showtooltip

/cast [@cursor] 百花齐放

-- 地毯指向宏

#showtooltip

/cast [@mouseover,help,exists][@player] 野性成长

-- 鼠标指向友方目标施法；没有指向则对自己施法。（对愈合、激变蜂群等同样适用）

#showtooltip

/cast [stance:2]斜掠

/cast [@mouseover,exists,harm]愤怒;愤怒

-- 猫形态斜掠；其他形态愤怒，有鼠标指向功能

#showtooltip

/cast [stance:2]痛击

/cast [@mouseover,exists,harm]阳炎术;阳炎术

-- 猫形态痛击；其他形态阳炎，有鼠标指向功能

#showtooltip

/cast [@mouseover,help,exists] 生命绽放

/cast [stance:2]横扫

/cast [stance:4]星火术

/cast 生命绽放

-- 鼠标指向友方生命绽放；猫形态横扫；咕形态星火；其他情况单放生命绽放

#showtooltip

/cast [@mouseover,exists,help]林莽卫士

/cast [stance:2]撕碎

/cast [@mouseover,exists,harm]月火术;月火术

-- 鼠标指向友方目标放树人；猫形态撕碎；其他情况月火，有鼠标指向功能

#showtooltip 树皮术

/cast 树皮术

/cast [nostance:1,nostealth]熊形态

/cast 狂暴回复

/cast [stance:1]熊形态

-- 释放树皮术；如果不是熊形态切非潜行状态则变熊；释放狂暴回复；如果是熊形态再变回人（容易连点变成人，不想要这条可以把最后一行删掉）

#showtooltip

/cast [@mouseover,help,exists,dead]复生

/cast [target=mouseover,help,exists,nodead][] 铁木树皮

-- 鼠标指向死去的友方目标战复；鼠标指向活着的友方目标给树皮；给当前目标树皮（当前目标是敌方可能会给到自己）

#showtooltip

/cast [target=mouseover,help,exists]迅捷治愈

/cast [stance:2]凶猛撕咬

/cast 自然迅捷

-- 鼠标指向友方目标释放迅捷治愈；如果是猫形态施放凶猛撕咬；释放自然迅捷

#showtooltip

/cast [@mouseover,help,exists]自然之愈

/cast [stance:2,harm]割裂

/cast 自然之愈

-- 鼠标指向友方目标驱散；猫形态割裂；其他形态施放驱散

#showtooltip

/cast [@mouseover,help,exists]塞纳里奥结界

/cast 野性之心

-- 鼠标指向友方对他施放结界；不指向则施放野性之心

#showtooltip

/cast [nostance:2]猎豹形态

/cast 迎头痛击

-- 如果不是猫形态则变猫，是猫形态就打断

#showtooltip

/cast [stance:3]狂奔怒吼

/cast 繁盛

/cast 自然的守护

-- 鹿形态狂奔怒吼；施放繁盛和自然的守护

/use [btn:2]雄壮远足牦牛;[mod:shift]雄壮远足牦牛

/use [swimming]!旅行形态;[indoors]!猎豹形态;[combat]!猎豹形态; [flyable]旅行形态; [outdoors]旅行形态

-- 鼠标右键牦牛；按住SHIFT+键位召唤牦牛；自动切换形态：游泳/可飞行/户外旅行形态，室内/战斗中猎豹形态

#showtooltip

/cast [btn:1]起死回生;[btn:2]新生

-- 左键单救，右键群活

#showtooltip

/cast [mod:alt]碧蓝魔酒;[@player]野性印记

/use 梦缚强化符文

-- 按住alt喝水，给自己上buff，用符文